Sicherung des Lizenzschlüssels

Aufgabenstellung

Unter Umständen kann es sich als sinnvoll oder notwendig erweisen, den 'The Bat!'-Lizenzschlüssel nach dessen Eingabe zur Registrierung der Applikation nochmals und separat anderweitiger 'The Bat!'-Programmeinstellungen zu sichern, beispielsweise um 'The Bat!' nach einer Neuinstallation automatisiert zu registrieren.

Internes
'The Bat!' speichert den Lizenzschlüssel nebst weiterer Programmeinstellungen innerhalb der Windows-Registrierungsdatenbank unter dem Pfad ”HKEY_CURRENT_USER\Software\RIT\The Bat!” und dem Schlüssel ”RegistrationBlock”.
Weiterführende Informationen zum Thema Speicherung von 'The Bat!'-Programmeinstellungen in Bezug auf die Windows-Registrierungsdatenbank hält der FAQ-Artikel ”Wo befinden sich welche Einstellungen/Informationen?” im Abschnitt ”4. Registry” bereit.

Procedere
Zur alleinigen Sicherung des Lizenzschlüssels stehen multiple Verfahrensweisen zur Verfügung. Besonders schnell und elegant vollzieht sich die Sicherung über eine sogenannte Batch-Datei – oder kurz BAT-Datei –, welche den Lizenzschlüssel automatisiert aus der Windows-Registrierungsdatenbank – oder kurz Windows-Registry – ausliest und in eine sogenannte Registrierungsdatei – oder kurz REG-Datei – zur späteren Verwendung schreibt.

BAT-Dateien
Eine BAT-Datei, auch Stapelverarbeitungsdatei genannt, beinhaltet eine Reihe von im Textformat vorliegenden Befehlsfolgen, welche vom Betriebssystem abgearbeitet werden.
BAT-Dateien tragen das Dateisuffix ”BAT” oder ”CMD” (Beispiele: ”BACKUP.BAT”; ”BACKUP.CMD”) und lassen sich in der DOS/Windows-Standardkonfiguration per einfacher Dateiausführung, bspw. durch einen direkten Namensaufruf (DOS) und/oder Doppelklick (Windows), starten.
BAT-Dateien kommen vorzugsweise bei der Ausführung wiederkehrender Aufgabenstellungen zum Einsatz und tragen so zu deren vereinfachten und beschleunigten Lösung bei.

REG-Dateien
Eine REG-Datei beinhaltet im allgemeinen Informationen aus der Windows-Registry, um sie auf dem Wege des Exportierens zu sichern und weiterzugeben sowie auf dem Wege des Importierens entgegenzunehmen und wieder in die Windows-Registry einzuspielen.
REG-Dateien sind mit dem Dateisuffix ”REG” (Beispiel: ”BACKUP.REG”) versehen und lassen sich in der Windows-Standardkonfiguration per einfacher Dateiausführung, bspw. durch einen direkten Doppelklick, der Windows-Registry hinzufügen.

Anwendung
Die vorgefertigte BAT-Datei ”TBKey-Backup.bat” (nachstehend dokumentiert) exportiert den 'The Bat!'-Lizenzschlüssel aus der Windows-Registry und speichert ihn in die REG-Datei ”TBKey.reg” desselben Verzeichnisses, in welchem auch die genannte BAT-Datei ihre Ablage hat.
Nach erfolgtem Download des ZIP-Archives TBKey-Backup.zip (s.u.) die darin enthaltene BAT-Datei – bspw. in das 'The Bat!'-Installationsverzeichnis – extrahieren und je nach Bedarf per einfacher Dateiausführung, etwa durch einen direkten Doppelklick, starten.
Die BAT-Datei ist zu den Betriebssystemen 'Windows 9x' bis 'Windows 7' kompatibel (ungetestet ≥ 'Windows 8') und kann mittels eines beliebigen Texteditors geöffnet und gemäß den persönlichen Anfordernissen modifiziert werden.

Dokumentation ”TBKey-Backup.bat”

Code:

@echo off
cls


set regfile=~tmp.reg
set keyfile=TBKey.reg




echo.
echo Der 'The Bat!'-Lizenzschlüssel wird gesichert.
echo Bitte warten . . .
echo.
echo.
ping -n 5 localhost>nul


regedit /a "%regfile%" "HKEY_CURRENT_USER\Software\RIT"


type %regfile% | find "RegistrationBlock">nul
if "%errorlevel%"=="1" goto ERROR


echo REGEDIT4>"%keyfile%"
echo.>>"%keyfile%"
echo ; Sicherungsdatei des The Bat!-Lizenzschluessels.>>"%keyfile%"
echo.>>"%keyfile%"
echo [HKEY_CURRENT_USER\Software\RIT\The Bat!]>>"%keyfile%"
type %regfile% | find "RegistrationBlock">>"%keyfile%"
echo.>>"%keyfile%"


cls
echo.
echo Sicherungsvorgang abgeschlossen.
echo.
echo Der 'The Bat!'-Lizenzschlüssel wurde in der Datei "%keyfile%" innerhalb des
echo 'The Bat!'-Installationsverzeichnisses gespeichert.
echo.
echo Zur Wiederherstellung der 'The Bat!'-Registrierung, bspw. nach einer Neuin-
echo stallation von 'The Bat!', die Datei "%keyfile%" ausführen.
goto END


:ERROR
cls
echo.
echo Fehler!
echo.
echo Sicherungsvorgang abgebrochen.
echo.
echo Innerhalb der Windows-Registry konnte kein 'The Bat!'-Lizenzschlüssels ge-
echo funden werden. Mögliche Ursache: 'The Bat!' ist nicht korrekt registriert.


:END
if exist "%regfile%" del "%regfile%"
if exist "%keyfile%" attrib -a "%keyfile%"


echo.
echo.
echo.
echo.
echo Zum Beenden dieses Sicherungsprogrammes eine beliebige Taste drücken.
pause>nul




set regfile=
set keyfile=

Eine Danke für diesen Artikel an Leela.