Backup Batch

c.bendt

Zitat

So geht das...

Um die Verwirrungen mal etwas zu entwirren:

Batch-Dateien werden aus Batch-Dateien mit einem CALL aufgerufen.
Dies stellt sicher, dass nach Beenden der aufgerufenen Batch-Datei wieder zur aufrufenden Batch-Datei zurückgesprungen wird.

Im Folgenden der korrekte Code:

Code

@echo off
pushd c:\programme\TheBat!\thebat!_backup
CALL TheBat!_Backup.bat
popd
start C:\programme\TheBat!\k9v1\k9.exe
start C:\programme\TheBat!\thebat.exe /nologo

Mit pushd (Win NT) wechselt man in das richtige Verzeichnis wobei sich das Verzeichnis in welchem man ursprünglich war gemerkt wird.
Mit popd (Win NT) wird wieder in das ursprüngliche Verzeichnis zurückgewechselt.

Das sollte helfen...

Klammeraffe

Hallo,

ich habe gerade die Batch-Backup-Funktion ueber den Task-Manager installiert. Laeuft auch prima und es klappt soweit. Habe die Batchdatei vom 12.12.03 für Thebat und K9 mal in Benutzung genommen. Der Backup wird ueber den Task gestartet und laeuft auch komplett durch; Nur was nicht funktioneirt, ist die Tatsache, dass er nur ein Backup pro Tag macht...der Task startet stuendlich und macht ein komplettes Backup jedesmal....

Die Abfrage, ob schon ein Backup vorhanden ist, wird doch in der Batchdatei gemacht, oder?
:denk:

caschy

klammeraffe

Siehe dein anderes Posting.

Postman

Hallo,

ich hatte nen Crash auf meinem System und nun ist die Batch Datei dahin ! Leider hab ich auch keine Sicherung von der Datei ! :cry: Ich hab schon gebastelt aber irgendwie will die Batch nicht laufen ! Ich wollte es diesmal mit WinRAR packen aber das Dos Fenster erscheint für ca. 2 Sekunden und ist danach wieder weg ! Könnte sich vielleicht jemand meiner Batchdatei annehmen ?! Ich häng sie mal an !!

Big THX.

Greetz

Postman

[gelöscht durch Administrator]

pjan

keine meldung?
führ die datei mal in einer konsole aus, also nicht per doppelklick starten. da sieht man nämlich auch was die batch so an meldungen ausspuckt.
start->ausführen->cmd

und

Code

:: Welches Programm wird für die Sicherung benutzt?
set ARCHIVER="C:\Programme\The Bat!\~RAR\rar.exe"

stimmt? du hast rar in deinem tb! verzeichnis liegen?

Postman

Hi pjan,

erst mal Danke für Deine Antwort ! Es war doch tatsächlich der WinRAR Pfad falsch angegeben.Ich dachte es reicht wenn man auf rar.exe hinweist! Dachte es sei ein eigenständiges Programm !

Jetzt läuft der Batch so wie er soll ! Nur leider funzt das nicht mit dem Terminplaner von TheBat! da kommt immer die Meldung das er TheBat!_Backup.bat nicht findet, jetzt habe ich es über den geplanten Task laufen da funzt es ohne Fehlermeldung ! Danke für den Tip !!

Greetz

Postman

scorpion08

Hallo,

gibt es eine Möglichkeit Bayesit mit in die Batch einzubinden.

scorpion08

nibbler

Hallo !

Eine Frage:

funktioniert die Batch-Datei mit 3er genauso gut :punk: , wie mit der 2er (das Mail-Verzeichnis ist im Bat-Ordner) ?

Danke im voraus.

caschy

Zitat

funktioniert die Batch-Datei mit 3er genauso gut :punk: , wie mit der 2er (das Mail-Verzeichnis ist im Bat-Ordner) ?.

Definitiv.

Mandarine

Hi Cashy,

nutze Deine batch nun auch schon ein weilchen mit Erfolg. Jetzt wollte ich das Target Dir ändern und zwar nach "eigene dateien".

Irgendwie komme ich da aber mit dem Leerzeichen nicht hin. Wenn ich das ganze in "Anführungszeichen" setze geht es auch nicht ...

Hast Du eine Idee?

Gruß

Sascha

yaqwa

dos pfad?

eigene ~

wäre ne möglichkeit

Bimbo Frogger

Ich habe ein Restore-Problem (Syntaxfehler beim Doppelklick auf die TheBat!_Restore.bat), sofern ich meinen tatsächlichen Installationspfad ("c:\programme\the bat!") in der TheBat!_Backup.bat angebe.

Hier die Anpassungen in der TheBat!_Backup.bat:

Code

:: Welche Dateien sollen gesichert werden?
:: The Bat! Installationsverzeichnis
set SOURCE_DIR="c:\programme\the bat!"


:: Wo sollen die gesicherten abgelegt werden?
set TARGET_DIR=D:\backup\TheBat!

Benenne ich nun das Installationsverzeichnis von "The Bat!" auf TheBat! um und ändere dies auch in der TheBat!_Backup.bat, dann geht der Restore nach erneutem Backup einwandfrei.

Zitat

:: Welche Dateien sollen gesichert werden?
:: The Bat! Installationsverzeichnis
set SOURCE_DIR="c:\programme\thebat!"

Funktioniert ein Restore nicht, sofern im Quellverzeichnis Leerzeichen vorhanden sind? Das Standard-Installationsverzeichnis von TheBat! lautet ja aber nunmal "The Bat!", und das möchte ich eigentlich auch ganz gerne beibehalten (zumal ich gar nicht weiß, was ich allers verbiegen müsste, um TheBat! auf ein von Hand umbenanntes Installationsverzeichznis anzupassen.

Achja: OS ist WinXP SP2

Ansonsten: Absolut geniale Batchdatei - super Sache

Vielen Dank
Bimbo Frogger

MoNeo

In Deinem einen Quoting fehlen die Anführungszeichen, die sind IMHO für Pfade mit Leerzeichen zwingend.

Ansonsten vielleicht mal versuchen, den DOS Namen dort einzugeben, das sind die mit der Tilde und den 8 Stellen (PROGRA~1 etc.)

Ansonsten fällt mir momentan auch nix ein... Wie geht denn die Fehlermeldung genau?

lazik

Zitat

@ECHO OFF
REM Archiwizacja poczty i danych programu The Bat!
REM Autor: Zygmunt Wereszczy?ski (7/03/2004)
REM Zmienna kontroluj?ca automatyczn? archiwizacj? (TAK/NIE)
REM SET AUTO_BACKUP=TAK
SET AUTO_BACKUP=TAK

REM ----------------Zmienne z nazwami katalogów-------------------
SET TB_MAIL_DIR="Z:\The Bat!\MailData"
SET TB_INST_DIR="Z:\The Bat!"
SET TB_ARCH_DIR="Z:\TB_Backup"
SET sleep="Z:\TB_Backup\sleep" 5
REM --------------------------------------------------------------
REM --------------Sprawdzenie czy Hamster dzia?a-----------------
REM (wymagane do odtworzenia tego stanu po wykonaniu archiwizacji)
FOR /F "TOKENS=1*" %%m IN ('pslist Hamster') DO SET HAMSTER_up=%%m
IF %HAMSTER_up%.==Hamster. (
SET HAMSTER_RUN=1
) ELSE (
SET HAMSTER_RUN=0 & GOTO :TB
)
REM --------------------------------------------------------------
D:\TB_Backup\pskill Hamster
REM --------------Sprawdzenie czy The Bat! dzia?a-----------------
REM (wymagane do odtworzenia tego stanu po wykonaniu archiwizacji)
:TB
FOR /F "TOKENS=1*" %%m IN ('pslist thebat') DO SET TB_up=%%m
IF %TB_up%.==thebat. (
SET TB_RUN=1
) ELSE (
SET TB_RUN=0 & GOTO :Kopiuj
)
REM --------------------------------------------------------------

IF %AUTO_BACKUP%==TAK GOTO :Automat

REM --------Oczekiwanie na zako?czenie pracy u?ytkownika----------
ECHO **************************************************************
ECHO Zachowaj dane - The Bat! bedzie zamkniety w celu archiwizacji!
ECHO Zapisz edytowane listy i nacisnij jakis klawisz!
ECHO Po archiwizacji The Bat! sam ponownie sie uruchomi!
ECHO **************************************************************
PAUSE
REM --------------------------------------------------------------

:Automat
REM Wys?anie polecenia zamkni?cia The Bat!
ECHO /EXIT >%TB_INST_DIR%\TheBat.IPC

REM ------------Oczekiwanie na zamkni?cie Hamstera----------------
:Sprawdzaj Hamstera
FOR /F "TOKENS=1*" %%m IN ('pslist Hamster') DO SET HAMSTER_up=%%m
IF %HAMSTER_up%.==Hamster. (
echo Proces "%HAMSTER_up%" jeszcze dziala, trzeba czekac... & %sleep%
) ELSE (
echo Proces "Hamster" zakonczony, mozna kopiowac & goto :Sprawdzaj TB
)
GOTO :Sprawdzaj Hamstera
REM --------------------------------------------------------------
REM ------------Oczekiwanie na zamkni?cie programu----------------
:Sprawdzaj TB
FOR /F "TOKENS=1*" %%m IN ('pslist thebat') DO SET TB_up=%%m
IF %TB_up%.==thebat. (
echo Proces "%TB_up%" jeszcze dziala, trzeba czekac... & %sleep%
) ELSE (
echo Proces "thebat" zakonczony, mozna kopiowac & goto :Kopiuj
)
GOTO :Sprawdzaj TB
REM --------------------------------------------------------------

:Kopiuj
REM ---------------Polecenia dla wrchiwizatorów-------------------
SET ARCH_CMD="Z:\TB_Backup\7zip\7z.exe" u -t7z
SET NAME_EXT=7z
REM Zmienna z poleceniem archiwizacji dla WinRar:
REM SET ARCH_CMD="C:\Program Files\winrar\rar.exe" a -u -as
REM Rozszerzenie nazwy archiwum dla Win Rar
REM SET NAME_EXT=rar
REM Jak wy?ej, lecz dla WZZIP:
REM SET ARCH_CMD="C:\Program Files\winzip\wzzip.exe" -u -b%TB_ARCH_DIR% -rp
REM SET NAME_EXT=zip
REM --------------------------------------------------------------

REM Dodatek do nazw archiwów z dat? i czasem (domy?lnie pusty):
SET dts=

REM ------------------Nazwy archiwów z dat?-----------------------
REM Tworzenie dodatku do nazw plików z dat? i czasem - nale?y
REM usun?? symbole poni?sze REM, gdy pliki maj? mie? nazwy z dat?:
REM SET parsearg="EOL=; TOKENS=1,2,3,4* DELIMS=/, "
REM FOR /F %parsearg% %%i IN ('DATE /t') DO SET ds=%%l%%k%%j
REM SET parsearg="EOL=; TOKENS=1,2* DELIMS=:, "
REM FOR /F %parsearg% %%i IN ('TIME /t') DO SET dts=_%ds%_%%i%%j
REM --------------------------------------------------------------

REM ----------------Zmienne z nazwami plików----------------------
SET TB_MAIL_ARCH=tbmail%dts%.%NAME_EXT%
SET TB_INST_ARCH=tbinst%dts%.%NAME_EXT%
SET TB_REG_ARCH=tbreg%dts%.reg
REM --------------------------------------------------------------

REM --------------Tworzenie (aktualizacja) archiwów---------------
REM 1. Archiwum katalogu z poczt?:
%ARCH_CMD% %TB_ARCH_DIR%\%TB_MAIL_ARCH% %TB_MAIL_DIR%
REM 2. Archiwum katalogu instalacyjnego:
%ARCH_CMD% %TB_ARCH_DIR%\%TB_INST_ARCH% %TB_INST_DIR%
REM 3. Kopia rejestru z wpisami The Bat!:
regedit /e %TB_ARCH_DIR%\%TB_REG_ARCH% HKEY_CURRENT_USER\Software\RIT
REM --------------------------------------------------------------
ECHO Gotowe...
REM Ponowne uruchamianie The Bat!
IF %HAMSTER_RUN%==1 START "Uruchom MobilBat" "Z:\The Bat!\uruchom.bat"
REM IF %TB_RUN%==1 START "Uruchom TB!" %TB_INST_DIR%\thebat.exe /NOLOGO
EXIT

Alles anzeigen

Bimbo Frogger

Zitat

In Deinem einen Quoting fehlen die Anführungszeichen, die sind IMHO für Pfade mit Leerzeichen zwingend.

Die sind doch vorhanden. Oder habe ich die irgendwie falsch gesetzt?

Zitat

Ansonsten vielleicht mal versuchen, den DOS Namen dort einzugeben, das sind die mit der Tilde und den 8 Stellen (PROGRA~1 etc.)

Werde ich mal versuchen - gefällt mir aber jetzt schon nicht.

Zitat

Ansonsten fällt mir momentan auch nix ein... Wie geht denn die Fehlermeldung genau?

Starte ich die TheBat!_Restore.bat per Doppelklick poppt kurz das schwarze DOS-Fenster auf und verschwindet wieder. Starte ich TheBat!_Restore.bat hingegen in der Eingabeaufforderung so erscheint lediglich der folgende Text in der Eingabeaufforderung:

Code

Automatisierte Ruecksicherung von The Bat!
-------------------------------------------------


Syntaxfehler.


D:\Backup\TheBat!\Backup#1>

Ändere ich von Hand den Inhalt der Quelle.dat von:
"c:\programme\the bat!" auf "c:\programme\thebat!", so funktioniert das Rückspielen einwandfrei - nur eben nicht in den gewünschten Ordner.

scorpion08

Welche Einstellungen muß ich in der bat vornehmen, wenn ich das ASP -Plugin mit sichern möchte.

scorpion08

Hammer0id

Ich poste einfach mal meine beiden .bat's

(Sichert Bayesfilter und ASP - K9 auskommentiert)

backup.bat:

Code

:: Batch-Datei für eine automatisierte Sicherung von The Bat! mit 
:: ausserhalb von TheBat! gelagerten Mailordnern (Optional)
:: und K9
:: Erstellt von P. Jansen, 12.12.2003
:: Modifiziert von Carsten Knobloch
:: www.batworld.de | www.batboard.de
::
:: Weitergabe nur mit Quellenangabe
::
:: Der Autor ist für Schäden/Verluste jeglicher Art nicht haftbar zu machen
:: Der Anwender trägt das Risiko der Nutzung
::
:: Wer kein K9 nutzt, der kommentiert folgende Zeilen aus: 77, 105, 109
::
:: Evtl. zu ändernde Pfadangaben sind vorhanden in Zeile: 24, 30, 33


::--------------------------------------------------------------------------------
@echo off
cls


if not %OS%==Windows_NT goto nont


:: The Bat! Installationsverzeichnis
set SOURCE_DIR="C:\Programme\The Bat!"


:: Welche Dateien sollen gesichert werden? (Optional)
set BAYESFILTER=bayes_reg.dat
set ASP=ASP_reg.dat
:: The Bat! Mit extra eMailsverzeichnis
:: Siehe TheBat! Optionen->Benutzereinstellungen->System->Nachrichtenverzeichnis)
:: ""= keine extra Maildaten sichern
set SOURCE_MAIL_DIR=""


:: Wo sollen die gesicherten abgelegt werden?
set TARGET_DIR=C:\tb_backup


set TARGET_DIR2=Backup#1
if exist "%TARGET_DIR%\%TARGET_DIR2%" set TARGET_DIR2=Backup#2
if exist "%TARGET_DIR%\%TARGET_DIR2%"% set TARGET_DIR2=Backup#3
if exist "%TARGET_DIR%\%TARGET_DIR2%" set TARGET_DIR2=Backup#4
if exist "%TARGET_DIR%\%TARGET_DIR2%" set TARGET_DIR2=Backup#5
if not exist "%TARGET_DIR%\%TARGET_DIR2%"% goto jump1


rmdir "%TARGET_DIR%\Backup#1" /s /q
move "%TARGET_DIR%\Backup#2" "%TARGET_DIR%\Backup#1"
move "%TARGET_DIR%\Backup#3" "%TARGET_DIR%\Backup#2"
move "%TARGET_DIR%\Backup#4" "%TARGET_DIR%\Backup#3"
move "%TARGET_DIR%\Backup#5" "%TARGET_DIR%\Backup#4"


:jump1


:: Verzeichnis für heutige Sicherung angelegen
set TARGET_DIR="%TARGET_DIR%\%TARGET_DIR2%"
md %TARGET_DIR%


:: Verzeichnis angelegt?
if not exist %TARGET_DIR% goto notargetdir


md %TARGET_DIR%\Data


:: Welches Programm wird für die Sicherung benutzt?
set ARCHIVER=~RAR\rar.exe


:: Sicherungsprogramm im angegebenen Pfad vorhanden?
if not exist %ARCHIVER% goto noarchiver


:: Welche Einstellungen sollen für die Sicherung benutzt werden?
set ARCHIVERCMD=%ARCHIVER% a -k -m0 -r -rr -dh -ep1


set XSOURCE_DIR=%SOURCE_DIR%\*.*
set XSOURCE_MAIL_DIR=%SOURCE_MAIL_DIR%\*.*


:: Welche Dateinamen sollen für die Sicherung benutzt werden?
set RARFILE=TheBat!.rar
set MAILFILE=TheBat!_Mails.rar
set REGFILE=TheBat!_reg.dat
set BATCHFILE=TheBat!_Backup.bat
set PROTFILE=Quelle.dat
set PROTFILE_MAIL=Quelle_Mail.dat
set RESTOREFILE=TheBat!_Restore.bat
::set K9REGFILE=K9_reg.dat
::set BAYESFILTER=bayes_reg.dat (steht schon oben)


:: The Bat! Installationsverzeichnis korrekt?
if not exist %SOURCE_DIR%\thebat.exe goto nothebat


:: The Bat! eMailverzeichnis korrekt?
if %SOURCE_MAIL_DIR%=="" goto jump2
if NOT exist %SOURCE_MAIL_DIR% goto nomaildir
:jump2


:: Sicherungsprogramm kopieren
copy ~RAR\unrar.exe %TARGET_DIR%\Data
IF not exist %TARGET_DIR%\Data\unrar.exe goto nounrarfile


:: Sicherung durchführen
%ARCHIVERCMD% %TARGET_DIR%\Data\%RARFILE% %XSOURCE_DIR%


:: Sicherung der Maildaten durchführen (im Extraverzeichnis)
if NOT %SOURCE_MAIL_DIR%=="" %ARCHIVERCMD% %TARGET_DIR%\Data\%MAILFILE% %XSOURCE_MAIL_DIR%


:: The Bat! Einstellungen aus der Registry exportieren ...
regedit /e %REGFILE% HKEY_CURRENT_USER\Software\RIT


:: ... und in das Zielverzeichnis verschieben
move %REGFILE% %TARGET_DIR%\Data\%REGFILE%


:: BayesFilter-Einstellungen auslesen und kopieren
regedit /e %BAYESFILTER% "HKEY_CURRENT_USER\Software\Bayes Filter Plugin"


move %BAYESFILTER% %TARGET_DIR%\Data\%BAYESFILTER%


::ASP-Einstellungen auslesen und kopieren
regedit /e %ASP% "HKEY_CURRENT_USER\Software\Gaijin"


move %ASP% %TARGET_DIR%\Data\%ASP%




:: K9 Einstellungen aus der Registry exportieren ...
:: Auskommentieren, wenn kein K9 vorhanden
:: regedit /e %K9REGFILE% HKEY_CURRENT_USER\Software\KeirNet


:: ... und in das Zielverzeichnis verschieben
:: Auskommentieren, wenn kein K9 vorhanden
:: move %K9REGFILE% %TARGET_DIR%\Data\%K9REGFILE%


:: Diese Batch-Datei ebenfalls sichern
copy %BATCHFILE% %TARGET_DIR%\Data\%BATCHFILE%.txt


:: Batch-Datei für die Rücksicherung kopieren
copy %RESTOREFILE% %TARGET_DIR%\%RESTOREFILE%


:: Protokollieren, welches Verzeichnis für die Sicherung benutzt wurde
echo %SOURCE_DIR%>%TARGET_DIR%\Data\%PROTFILE%


:: Protokollieren, welches Verzeichnis für die Sicherung der Maildaten benutzt wurde
if NOT %SOURCE_MAIL_DIR%=="" echo %SOURCE_MAIL_DIR%>%TARGET_DIR%\Data\%PROTFILE_MAIL%


:: Prüfen, ob alle Dateien vorhanden sind
if not exist %TARGET_DIR%\%RESTOREFILE% goto norestorefile
if not exist %TARGET_DIR%\Data\%RARFILE% goto norarfile
if not exist %TARGET_DIR%\Data\%REGFILE% goto noregfile
if not exist %TARGET_DIR%\Data\%BATCHFILE%.txt goto nobatchfile
if not exist %TARGET_DIR%\Data\%PROTFILE% goto noprotfile
if %SOURCE_MAIL_DIR%=="" goto jump3
if not exist %TARGET_DIR%\Data\%MAILFILE% goto nomailfile
if not exist %TARGET_DIR%\Data\%PROTFILE_MAIL% goto nomailprotfile
:jump3


:: Datum der letzten Sicherung speichern
:: echo %DATE%>backup.dat


goto end


:nont
echo.
echo FEHLER: Kein Windows NT System!
pause
goto end


:: Packprogramm nicht gefunden
:noarchiver
echo.
echo FEHLER: Packprogramm %ARCHIVER% nicht gefunden!
pause
goto end


:: Falsches The Bat! Installationsverzeichnis
:nothebat
echo.
echo FEHLER: Falsches The Bat! Installationsverzeichnis (SOURCE_DIR)!
pause
goto end


:: Falsches The Bat! eMailverzeichnis
:nomaildir
echo.
echo FEHLER: Falsches The Bat! eMailverzeichnis %SOURCE_MAIL_DIR% (SOURCE_MAIL_DIR)!
pause
goto end


:: Sicherungsverzeichnis konnte nicht angelegt werden
:notargetdir
echo.
echo FEHLER: Sicherungsverzeichnis konnte nicht angelegt werden (TARGET_DIR)!
pause
goto end


:: Fehlende Dateien
:norarfile
echo.
echo FEHLER: Datei %TARGET_DIR%\Data\%RARFILE% nicht gefunden!
pause
goto end


:nomailfile
echo.
echo FEHLER: Datei %TARGET_DIR%\Data\%MAILFILE% nicht gefunden!
pause
goto end


:noregfile
echo.
echo FEHLER: Datei %TARGET_DIR%\Data\%REGFILE% nicht gefunden!
pause
goto end


:nobatchfile
echo.
echo FEHLER: Datei %TARGET_DIR%\Data\%BATCHFILE%.txt nicht gefunden!
pause
goto end


:norestorefile
echo.
echo FEHLER: Datei %TARGET_DIR%\%RESTOREFILE% nicht gefunden!
pause
goto end


:noprotfile
echo.
echo FEHLER: Datei %TARGET_DIR%\Data\%PROTFILE% nicht gefunden!
pause
goto end


:nomailprotfile
echo.
echo FEHLER: Datei %TARGET_DIR%\Data\%PROTFILE_MAIL% nicht gefunden!
pause
goto end


:nounrarfile
echo.
echo FEHLER: Datei %TARGET_DIR%\Data\unrar.exe nicht gefunden!
pause
goto end


:: Sicherung beendet
:end

Alles anzeigen

restore.bat:

Code

:: Wer kein K9 nutzt, kommentiert folgende Zeilen aus: 23,28,60
::
::
::
::
::


@echo off
cls


echo Automatisierte Ruecksicherung von The Bat!
echo -------------------------------------------------
echo.


if not %OS%==Windows_NT goto nont


:: Prüfen, ob alle Dateien vorhanden sind
set TARGETFILE=Quelle.dat
set RARFILE=TheBat!.rar
set TARGETMAILFILE=Quelle_Mail.dat
set MAILFILE=TheBat!_Mails.rar
set REGFILE=TheBat!_reg.dat
::set K9REGFILE=K9_reg.dat
set BAYESFILTER=bayes_reg.dat
set ASP=ASP_reg.dat


if not exist Data\%TARGETFILE% goto notargetfile
if not exist Data\%RARFILE% goto norarfile
if not exist Data\%REGFILE% goto noregfile
if not exist Data\%BAYESFILTER% goto noregfile
if not exist Data\%ASP% goto noregfile
::if not exist Data\%K9REGFILE% goto noregfile




:: Welches Programm wird für die Rücksicherung benutzt?
set ARCHIVER=Data\unrar.exe


:: Sicherungsprogramm im angegebenen Pfad vorhanden?
if not exist %ARCHIVER% goto noarchiver


:: FOR /F "TOKENS=1" %%I IN (Data\%TARGETFILE%) DO SET TARGET_DIR=%%I //<------- Machte bei mir Probleme wenn ein Space im Pfad war!
FOR /F "delims=,." %%A IN (Data\%TARGETFILE%) DO SET TARGET_DIR=%%A


if exist %TARGET_DIR% rmdir %TARGET_DIR% /s /q
if exist %TARGET_DIR% goto normdir


mkdir %TARGET_DIR%
if not exist %TARGET_DIR% goto nodir


:: Welche Einstellungen sollen für die Rücksicherung benutzt werden?
set ARCHIVERCMD=%ARCHIVER% x -r


:: Rücksicherung durchführen
%ARCHIVERCMD% %RARFILE% %TARGET_DIR%


:: Verzeichnis angelegt?
if not exist %TARGET_DIR% goto nodir


:: The Bat! Einstellungen in die Registry importieren ...
:: /s = keine Sicherheitsabfrage
regedit /s Data\%REGFILE%


:: K9 Einstellungen in die Registry importieren


::regedit /s Data\%K9REGFILE%


:: Bayesfilter Einstellungen in die Registry importieren
regedit /s Data\%BAYESFILTER%


:: ASP Einstellungen in die Registry importieren
regedit /s Data\%ASP%


:: Müssen noch die Maildaten rückgesicht werden?
if not exist Data\%TARGETMAILFILE% goto end
if not exist Data\%MAILFILE% goto nomail
:: FOR /F "TOKENS=1" %%I IN (Data\%TARGETMAILFILE%) DO SET TARGET_DIR=%%I //<------- Machte bei mir Probleme wenn ein Space im Pfad war!
FOR /F "delims=,." %%A IN (Data\%TARGETMAILFILE%) DO SET TARGET_DIR=%%A


if exist %TARGET_DIR% rmdir %TARGET_DIR% /s /q
if exist %TARGET_DIR% goto normdir


mkdir %TARGET_DIR%
if not exist %TARGET_DIR% goto nodir


:: Welche Einstellungen sollen für die Rücksicherung benutzt werden?
set ARCHIVERCMD=%ARCHIVER% x -r


:: Rücksicherung der eMaildaten durchführen
%ARCHIVERCMD% %MAILFILE% %TARGET_DIR%


:: Verzeichnis angelegt?
if not exist %TARGET_DIR% goto nodir


goto end


:nont
echo.
echo FEHLER: Kein Windows NT System!
pause
goto end


:notargetfile
echo.
echo FEHLER: Datei Data\%TARGETFILE% nicht gefunden!
pause
goto end


:norarfile
echo.
echo FEHLER: Datei Data\%RARFILE% nicht gefunden!
pause
goto end


:noregfile
echo.
echo FEHLER: Datei Data\%REGFILE% nicht gefunden!
pause
goto end




:normdir
echo.
echo FEHLER: Loeschen des Verzeichnis %TARGET_DIR% nicht moeglich!
pause
goto end


:nodir
echo.
echo FEHLER: Anlegen des Verzeichnis %TARGET_DIR% nicht moeglich!
pause
goto end


:noarchiver
echo.
echo FEHLER: Programm Data\%ARCHIVER% nicht gefunden!
pause
goto end


:nomail
echo.
echo FEHLER: Mail-Daten Data\%MAILFILE% nicht gefunden!
pause
goto end


:: Sicherung beendet
:end

Alles anzeigen

scorpion08

@ Hammer0id

Danke für deine bat.
Sie funzt ohne Probleme.

scorpion08

doc0815

moin zusammen!

Ich bin neu hier im board, nutze aber the bat schon länger.
Habe vor einer neu stall des os ein backup von the bat mit dem patch aus dem downloadbereich gemacht.
Das backup hat auch gefunzt, nun zum prob das restore funzt nicht :cry:
Habe diesen Thread schon 2x duchgeackert aber habe nicht gefunden was ein restore ermöglicht.
Mein os ist winxp+sp2 batversion 3.xxx
Die fehlermeldung ->datei data\quelle nicht gefunden obwohl sie da ist und wenn ich den inhalt der datei d:\programme\thebat ändere spiel das patch zwar die mailaccounts zurück aber ohne inhalt und funktion.
Soll ich mal die patchdatei posten damit es sich mal einer anschauen kann wo der fehler liegt?

cu doc0815

caschy

Easy going:

Backup-Datei mit Rar entpacken. Ordner an die alte Stelle legen, Reg importieren - läuft.